FDR/FDR.iso/DATA/16_1.Dxr/00002_Overview Main.ls

Text File | 1996-10-22 | 5.2 KB | 200 lines

global vOpt, vSOpt, vFOpt, vVoid, vHFlag19, vHFlag47, vHFlag48, vThreadRect, vYearList, vChronList, vForList, vNatList, vFdrList, vErList, vAmList

on OverViewHilight
  set mLoc to point(the mouseH, the mouseV)
  if inside(mLoc, rect(290, 0, 445, 135)) then
    threads(mLoc)
  else
    if inside(mLoc, rect(0, 135, 640, 450)) then
      cellHilight(mLoc)
    else
      if inside(mLoc, rect(130, 450, 510, 480)) then
        SBArrowHilight(mLoc)
      end if
    end if
  end if
end

on overviewDown
  set cLoc to the clickLoc
  set cOn to the clickOn
  if inside(cLoc, rect(0, 135, 640, 450)) then
    cellDown(cOn)
  else
    if inside(cLoc, rect(130, 450, 510, 480)) then
      SBDown(cLoc)
    end if
  end if
end

on SBDown cLoc
  set sbRects to value(the text of field "sbRects")
  set maxCtr to count(sbRects)
  repeat with ctr = 1 to maxCtr
    set rct to getAt(getAt(sbRects, ctr), 1)
    set lbl to getAt(getAt(sbRects, ctr), 2)
    if inside(cLoc, rct) and (label(lbl) <> the frame) then
      clickWait()
      if inside(point(the mouseH, the mouseV), rct) then
        setCursor(4)
        go(lbl)
        moveSprite(17, point(162 + ((the frame - 1) * 16), the locV of sprite 17), 1)
        thumbYear()
        set vFOpt to the frame
        setCursor(0)
      end if
      abort()
    end if
  end repeat
end

on cellHilight mLoc
  repeat with ctr = 19 to 44
    if rollOver(ctr) then
      if vHFlag19 = ("c" & ctr) then
        abort()
      end if
      set whichCell to the name of member the memberNum of sprite ctr
      delete char -30000 of whichCell
      set thd to getAt(getAt(vChronList, value(whichCell)), 2)
      hideMovieHilights()
      set the visible of sprite ctr to 1
      showThreads(thd)
      showPrev("pic" & vOpt & "," & whichCell & ",1")
      hideHilights([47, 48])
      set vHFlag19 to "c" & ctr
      abort()
    end if
  end repeat
end

on cellDown cLoc
  repeat with ctr = 19 to 44
    if cLoc = ctr then
      clickWait()
      if inside(point(the mouseH, the mouseV), the rect of sprite ctr) then
        setCursor(4)
        set whichCell to the name of member the memberNum of sprite ctr
        delete char -30000 of whichCell
        do("doOpt16(value(whichCell), 1)")
        set the visible of sprite ctr to 0
      end if
      abort()
    end if
  end repeat
end

on SBArrowHilight mLoc
  if inside(mLoc, rect(133, 451, 146, 480)) and (the frame <> label("1896")) then
    if vHFlag48 <> "lArrow" then
      showSprite(48, "sbLeftH", point(139, 465), 0)
      hideHilights([47, 46])
      hideMovieHilights()
      set vHFlag48 to "lArrow"
    end if
    abort()
  else
    if inside(mLoc, rect(403, 451, 416, 480)) and (the frame <> label("1953")) then
      if vHFlag48 <> "rArrow" then
        showSprite(48, "sbRightH", point(409, 465), 0)
        hideHilights([47, 46])
        hideMovieHilights()
        set vHFlag48 to "rArrow"
      end if
      abort()
    end if
  end if
end

on thumbYear
  set maxCtr to count(vYearList)
  repeat with ctr = 1 to maxCtr
    set x to getAt(getAt(vYearList, ctr), 1)
    set y to getAt(getAt(vYearList, ctr), 2)
    if (the left of sprite 17 >= x) and (the left of sprite 17 <= y) then
      set s to getAt(getAt(vYearList, ctr), 3)
      swapSprite(17, s, 1)
      exit repeat
    end if
  end repeat
end

on threads mLoc
  repeat with ctr = 7 to 11
    if rollOver(ctr) then
      if vHFlag19 = ("c" & ctr) then
        abort()
      end if
      hideMovieHilights()
      hideHilights([46, 47])
      case ctr of
        7:
          showThreads([1])
          set thdLst to getAt(vForList, the frame)
        8:
          showThreads([2])
          set thdLst to getAt(vNatList, the frame)
        9:
          showThreads([3])
          set thdLst to getAt(vFdrList, the frame)
        10:
          showThreads([4])
          set thdLst to getAt(vErList, the frame)
        11:
          showThreads([5])
          set thdLst to getAt(vAmList, the frame)
      end case
      set maxCtr2 to count(thdLst)
      repeat with ctr2 = 1 to maxCtr2
        set whichCell to getAt(thdLst, ctr2)
        repeat with ctr3 = 19 to 44
          if the name of member the memberNum of sprite ctr3 = (whichCell & "H") then
            set the visible of sprite ctr3 to 1
            exit repeat
          end if
        end repeat
      end repeat
      updateStage()
      set vHFlag19 to "c" & ctr
      abort()
    end if
  end repeat
  if vHFlag19 <> 0 then
    swapSprite(7, "For", 0)
    swapSprite(8, "Nat", 0)
    swapSprite(9, "FDR", 0)
    swapSprite(10, "ER", 0)
    swapSprite(11, "Am", 0)
    repeat with x = 19 to 44
      set the visible of sprite x to 0
    end repeat
    updateStage()
    set vHFlag19 to vVoid
  end if
end

on showThreads threadList
  set maxCtr to count(threadList)
  repeat with ctr = 1 to maxCtr
    if getAt(threadList, ctr) = 1 then
      swapSprite(7, "hFor", 0)
      next repeat
    end if
    if getAt(threadList, ctr) = 2 then
      swapSprite(8, "hNat", 0)
      next repeat
    end if
    if getAt(threadList, ctr) = 3 then
      swapSprite(9, "hFDR", 0)
      next repeat
    end if
    if getAt(threadList, ctr) = 4 then
      swapSprite(10, "hER", 0)
      next repeat
    end if
    if getAt(threadList, ctr) = 5 then
      swapSprite(11, "hAm", 0)
    end if
  end repeat
end